鴻蒙內核源碼分析(匯編匯總篇) | 鴻蒙所有的匯編代碼都在這里
匯編其實很可愛
● 絕大部分IT從業人員終生不用觸碰到的匯編,它聽著像上古時代遙遠的呼喚,總覺得遠卻又能聽到聲,匯編再往下就真的是01110011了,匯編指令基本是一一對應了機器指令.
● 所謂內核是對硬件的驅動,對驅動之后資源的良序管理,這里說的資源是CPU(單核/多核),內存,磁盤,i/o設備.層層封裝,步步遮蔽,到了應用層,不知有漢,無論魏晉才好.好是好,但有句話,其實哪有什么歲月靜好,只是有人替你負重前行.難道你真的不想知道別人是怎么替你負重前行的?
● 越高級的語言是越接近人思維模式的,越低級的語言就是越貼近邏輯與非門的高低電平的起伏.匯編是貼著硬件飛行的,要研究內核就繞不過匯編,覺得神秘是來源于不了解,恐懼是來自于沒接近.
● 其實當你深入分析內核源碼之后就會發現,匯編其實很可愛,很容易,比c/c++/java容易太多了,真的是很傻很單純.
鴻蒙內核源碼分析系列篇至少已經有五篇涉及到了匯編,請自行翻看,但還是遠遠不夠,要寫十五篇,徹底摸透,現在才剛剛開始,本篇先整理鴻蒙內核所有匯編文件和大概說明文件的作用,后續一塊一塊來剝,不把這些匯編剝個精光不罷休.
匯編目錄
鴻蒙所有匯編文件如下: 直接點擊可以查看注解源碼,有些站點會把鏈接去除,沒辦法,可直接去各大站點搜"鴻蒙內核源碼分析",找到源碼注解.
● \arch\arm\arm\src
◆ startup 啟動相關
◆ reset_vector_mp.S 多核CPU下啟動代碼,大文件
◆ reset_vector_up.S 單核CPU下啟動代碼,大文件
◆ armv7a
◆ cache.S 緩存相關的兩個函數
◆ los_dispatch.S 異常分發處理,大文件.
◆ los_hw_exc.S 硬件異常相關,大文件.
◆ los_hw_runstop.S OsSRSaveRegister 和 OsSRRestoreRegister 匯編實現
◆ jmp.S 兩個簡單的跳轉函數
◆ hw_user_get.S 拷貝用戶空間數據到內核空間
◆ hw_user_put.S 拷貝內核空間數據到用戶空間
hw_user_get.S
將用戶空間數據src 拷貝到內核空間 dst
- // errno_t _arm_get_user(void *dst, const void *src, size_t dstTypeLen, size_t srcTypeLen)
- FUNCTION(_arm_get_user)
- stmdb sp!, {r0, r1, r2, r3, lr} @四個參數入棧,保存LR
- cmp r2, #0 @r2 和 0比較
- beq .Lget_user_return @相等 跳到Lget_user_return 直接返回
- cmp r2, r3 @r2 和 r3比較
- bne .Lget_user_err @不等,說明函數要返回錯誤
- cmp r2, #1 @r2 和 1比較
- bhi .Lget_user_half @if(dstTypeLen>1) 跳轉到Lget_user_half
- .Lget_user_byte: @按字節拷貝數據
- 0: ldrbt r3, [r1], #0 @r3=*r1
- 1: strb r3, [r0], #0 @*r0=r3
- b .Lget_user_return
- .Lget_user_half:
- cmp r2, #2 @r2 和 2比較
- bhi .Lget_user_word @if(dstTypeLen>2) Lget_user_word
- 2: ldrht r3, [r1], #0 @完成最后一個字節的拷貝
- 3: strh r3, [r0], #0 @完成最后一個字節的拷貝
- b .Lget_user_return
- .Lget_user_word:
- cmp r2, #4 @r2 和 4比較
- bhi .Lget_user_err @if(dstTypeLen>4) 跳轉到Lget_user_err
- 4: ldrt r3, [r1], #0
- 5: str r3, [r0], #0
- .Lget_user_return: @返回錨點
- ldmia sp!, {r0, r1, r2, r3, lr} @保存的內容出棧,恢復各寄存器值
- mov r0, 0 @r0保存返回值為0
- bx lr @跳回調用函數繼續執行,_arm_get_user到此結束!
- .Lget_user_err:
- ldmia sp!, {r0, r1, r2, r3, lr} @保存的內容出棧,恢復各寄存器值
- mov r0, #-14 @r0保存返回值為-14
- bx lr @跳回調用函數繼續執行,_arm_get_user到此結束!
- .pushsection __exc_table, "a"
- .long 0c, .Lget_user_err
- .long 1c, .Lget_user_err
- .long 2c, .Lget_user_err
- .long 3c, .Lget_user_err
- .long 4c, .Lget_user_err
- .long 5c, .Lget_user_err
- .popsection
hw_user_put.S
將內核空間數據src 拷貝到用戶空間 dst
- // errno_t _arm_put_user(void *dst, const void *src, size_t dstTypeLen, size_t srcTypeLen)
- FUNCTION(_arm_put_user)
- stmdb sp!, {r0, r1, r2, r3, lr}
- cmp r2, #0
- beq .Lget_user_return
- cmp r2, r3
- bne .Lget_user_err
- cmp r2, #1
- bhi .Lget_user_half
- .Lget_user_byte:
- 0: ldrb r3, [r1], #0
- 1: strbt r3, [r0], #0
- b .Lget_user_return
- .Lget_user_half:
- cmp r2, #2
- bhi .Lget_user_word
- 2: ldrh r3, [r1], #0
- 3: strht r3, [r0], #0
- b .Lget_user_return
- .Lget_user_word:
- cmp r2, #4
- bhi .Lget_user_err
- 4: ldr r3, [r1], #0
- 5: strt r3, [r0], #0
- .Lget_user_return:
- ldmia sp!, {r0, r1, r2, r3, lr}
- mov r0, 0
- bx lr
- .Lget_user_err:
- ldmia sp!, {r0, r1, r2, r3, lr}
- mov r0, #-14
- bx lr
- .pushsection __exc_table, "a"
- .long 0c, .Lget_user_err
- .long 1c, .Lget_user_err
- .long 2c, .Lget_user_err
- .long 3c, .Lget_user_err
- .long 4c, .Lget_user_err
- .long 5c, .Lget_user_err
- .popsection
解讀
● 如果仔細對比一下發現這兩個函數的匯編代碼是一模一樣的,沒有區別.這就跟讓左右各一個美女陪你和左右各一個丑姑娘陪你的道理是一樣,都是1+1=2,算式加法的邏輯是一樣的,不會變.但給你的感覺能一樣嘛,美丑的含義是上層賦予的,到了這里美丑不重要,都變成了 r0,r1,r2,r3了, 跟咱東哥一樣臉盲分不清啦
● 用戶空間和內核空間的數據為什么需要拷貝? 這是個經典問題,看了網上的一些回答,沒毛病:
內核不能信任任何用戶空間的指針。必須對用戶空間的指針指向的數據進行驗證。如果只做驗證不做拷貝的話，那么在隨后的運行中要隨時受到其它進/線程可能修改用戶空間數據的威脅。所以必須做拷貝。
在內存系列篇中已經反復的說過,每個用戶進程都有自己獨立的用戶空間,但這個用戶空間是通過MMU映射出來的,是表面上繁花似錦,背后都共用著真正的物理內存,所以在高頻率的任務切換過程中,原有的用戶空間地址內容很容易被覆蓋掉.舉個例子說明下:
◊ 用戶A客戶有個美女放在萬聰酒店21號房說要獻給內核大佬,如果內核不直接把美女接回家,而僅僅是做個記錄,寫著美女在萬聰酒店21號房,內核立馬跑去過還好不會錯,但如果被其他事給耽擱了呢?
◊ 耽擱的這回功夫,調度算法把萬聰酒店21號房給了B客戶使用,當然B客戶用之前酒店管理人員會把美女置換個地方(以至于A客戶再回到酒店時,原來的東西該怎樣還咋樣). 等21號房空出來了,B肯定不知道原來的房間是A在用,而且里面還有個美女,更不可能曉得美女獻給內核大佬了.因為B的業務需要,很可能往21號房整了個東施進來.
◊ 此時如果內核大佬事忙完了,想起A客戶獻美女的事了,是時候了.因為只記錄了地址,直接去萬聰酒店21號房抓人,那抓出來可是東施呀.這可不把事給搞砸啦.
◊ 所以需要拷貝,直接把美女接回家找個地方關起來先.
reset_vector_mp.S 和 reset_vector_up.S
鴻蒙開機代碼根據 CPU多核還是單核分成了兩個獨立文件處理. mp就是多處理器(multiprocessing)的意思: 多CPU核的操作系統3種處理模式(SMP+AMP+BMP) 鴻蒙實現的是 SMP 的方式
● 非對稱多處理(Asymmetric multiprocessing，AMP)每個CPU內核 運行一個獨立的操作系統或同一操作系統的獨立實例(instantiation)。
● 對稱多處理(Symmetric multiprocessing，SMP)一個操作系統的實例 可以同時管理所有CPU內核，且應用并不綁定某一個內核。
● 混合多處理(Bound multiprocessing，BMP)一個操作系統的實例可以 同時管理所有CPU內核，但每個應用被鎖定于某個指定的核心。
up(unit processing )的意思,單個CPU,雖然沒mp的復雜,但文件也很大 500行匯編,一小節講不完,需要單獨的一篇專講 reset_vector
這里只列出up情況下的開機代碼
- reset_vector: @鴻蒙單核cpu 開機代碼
- /* do some early cpu setup: i/d cache disable, mmu disabled */
- mrc p15, 0, r0, c1, c0, 0
- bic r0, #(1<<12)
- bic r0, #(1<<2 | 1<<0)
- mcr p15, 0, r0, c1, c0, 0
- /* r11: delta of physical address and virtual address */
- adr r11, pa_va_offset
- ldr r0, [r11]
- sub r11, r11, r0
- /* if we need to relocate to proper location or not */
- adr r4, __exception_handlers /* r4: base of load address */
- ldr r5, =SYS_MEM_BASE /* r5: base of physical address */
- subs r12, r4, r5 /* r12: delta of load address and physical address */
- beq reloc_img_to_bottom_done /* if we load image at the bottom of physical address */
- /* we need to relocate image at the bottom of physical address */
- ldr r7, =__exception_handlers /* r7: base of linked address (or vm address) */
- ldr r6, =__bss_start /* r6: end of linked address (or vm address) */
- sub r6, r7 /* r6: delta of linked address (or vm address) */
- add r6, r4 /* r6: end of load address */
los_dispatch.S 和 los_hw_exc.S
異常模式處理入口和統一分發現實,之前也有提到過,很復雜,1000多行,后續單獨細說實現過程.
jmp.S
兩個簡單的函數longjmp setjmp 的實現,加注解部分請前往 鴻蒙內核源碼注解分析 查看
- FUNCTION(longjmp)
- ldmfd r0,{r4-r12}
- add r0,#(4 * 9)
- ldr r13,[r0]
- add r0,#4
- ldr r14,[r0]
- cmp r1,#0
- moveq r1,#1
- mov r0,r1
- mov pc,lr
- FUNCTION(setjmp)
- stmea r0,{r4-r12}
- add r0,#(4 * 9)
- str r13,[r0]
- add r0,#4
- str r14,[r0]
- mov r0,#0
- mov pc,lr
los_hw_runstop.S
- .global OsSRSaveRegister
- .global OsSRRestoreRegister
兩個函數的匯編現實,有點復雜,后續單獨說明.
cache.S
這是緩存部分的兩個函數實現,此處沒有加注解,試著看明白這兩個函數的實現.加注解部分請前往 鴻蒙內核源碼注解分析 查看
- .macro DCACHE_LINE_SIZE, reg, tmp
- mrc p15, 0, \tmp, c0, c0, 1
- lsr \tmp, \tmp, #16
- and \tmp, \tmp, #0xf
- mov \reg, #4
- mov \reg, \reg, lsl \tmp
- .endm
- FUNCTION(arm_inv_cache_range)
- push {r2, r3}
- DCACHE_LINE_SIZE r2, r3
- sub r3, r2, #1
- tst r0, r3
- bic r0, r0, r3
- mcrne p15, 0, r0, c7, c14, 1
- tst r1, r3
- bic r1, r1, r3
- mcrne p15, 0, r1, c7, c14, 1
- 1:
- mcr p15, 0, r0, c7, c6, 1
- add r0, r0, r2
- cmp r0, r1
- blo 1b
- dsb
- pop {r2, r3}
- mov pc, lr
- FUNCTION(arm_clean_cache_range)
- push {r2, r3}
- DCACHE_LINE_SIZE r2, r3
- sub r3, r2, #1
- bic r0, r0, r3
- 1:
- mcr p15, 0, r0, c7, c10, 1
- add r0, r0, r2
- cmp r0, r1
- blo 1b
- dsb
- pop {r2, r3}
- mov pc, lr
參與貢獻
● 訪問注解倉庫地址
● Fork 本倉庫 >> 新建 Feat_xxx 分支 >> 提交代碼注解 >> 新建 Pull Request
● 新建 Issue
