鴻蒙內(nèi)核源碼分析(異常接管篇) | 中文注解HarmonyOS源碼
51CTO和華為官方合作共建的鴻蒙技術(shù)社區(qū)
為何要有異常接管?
拿小孩成長打比方,大人總希望孩子能健康成長,但在成長過程中總會遇到各種各樣的問題,樹欲靜而風(fēng)不止,成長路上有危險,有時是自己的問題有時是外在環(huán)境問題.就像抖音最近的流行口水歌一樣,社會很單純,復(fù)雜的是人啊,每次聽到都想站起來扭幾下.哎! 老衲到底做錯什么了?
比如:老被小朋友欺負(fù)怎么弄? 發(fā)現(xiàn)亂花錢怎么搞? 青春期發(fā)育怎么應(yīng)對? 失戀要跳樓又怎么辦? 意思超過他的認(rèn)知范圍,就是靠它自己解決不了了,就需要有更高權(quán)限,更高智慧的人介入進(jìn)來,幫著解決,干擦屁股的事.
那么應(yīng)用程序就是那個小孩,內(nèi)核就是監(jiān)護(hù)人,有更高的權(quán)限,更高的智慧.而且監(jiān)護(hù)人還不止一個,而是六個,每個監(jiān)護(hù)人對應(yīng)解決一種情況,情況發(fā)生了就由它來接管這件事的處理,小朋友你就別管了,先把你關(guān)家里,處理好了外面安全了再把應(yīng)用程序放出來玩去.
這六個人處理問題都自帶工具,有標(biāo)準(zhǔn)的解決方案,有自己獨(dú)立的辦公場所,辦公場所就是棧空間(獨(dú)立的),標(biāo)準(zhǔn)解決方案就是私有代碼段,放在固定的位置.而自帶的工具就是 SPSR_***,SP_***,LR_***寄存器組.詳見 系列篇之工作模式篇 ,這里再簡單回顧下有哪些工作模式,包括小孩自己(用戶模式)一共是七種模式.
七種工作模式
圖來源于 ARM720T.pdf第43頁,在ARM體系中,CPU工作在以下七種模式中:
● 用戶模式(usr)：屬于正常的用戶模式，不能直接切換到其他模式,ARM處理器正常的程序執(zhí)行狀態(tài)。
● 快速中斷模式(fiq)：支持高速數(shù)據(jù)傳輸及通道處理，F(xiàn)IQ異常響應(yīng)時進(jìn)入此模式
● 外部中斷模式(irq)：用于通用中斷處理，IRQ異常響應(yīng)時進(jìn)入此模式
● 管理模式(svc)：操作系統(tǒng)保護(hù)模式，系統(tǒng)復(fù)位和軟件中斷響應(yīng)時進(jìn)入此模式(由系統(tǒng)調(diào)用執(zhí)行軟中斷SWI命令觸發(fā))
● 數(shù)據(jù)訪問終止模式(abt)：當(dāng)數(shù)據(jù)或指令預(yù)取終止時進(jìn)入該模式，可用于處理存儲器故障、實(shí)現(xiàn)虛擬存儲器和存儲器保護(hù)。
● 系統(tǒng)模式(sys)：運(yùn)行具有特權(quán)的操作系統(tǒng)任務(wù),與用戶模式類似，但具有可以直接切換到其他模式等特權(quán)
● 未定義指令中止模式(und)：處理未定義的指令陷阱，當(dāng)未定義的指令執(zhí)行時進(jìn)入該模式，可用于支持硬件協(xié)處理器的軟件仿真。
除用戶模式外，其余6種工作模式都屬于特權(quán)模式
● 特權(quán)模式中除了系統(tǒng)模式以外的其余5種模式稱為異常模式
● 大多數(shù)程序運(yùn)行于用戶模式
● 進(jìn)入特權(quán)模式是為了處理中斷、異常、或者訪問被保護(hù)的系統(tǒng)資源
● 硬件權(quán)限級別：系統(tǒng)模式 > 異常模式 > 用戶模式
● 快中斷(fiq)與慢中斷(irq)區(qū)別：快中斷處理時禁止中斷
每種模式都有自己獨(dú)立的入口和獨(dú)立的運(yùn)行棧空間. 系列篇之CPU篇 已介紹過只要提供了入口函數(shù)和運(yùn)行空間,CPU就可以干活了.入口函數(shù)解決了指令來源問題,運(yùn)行空間解決了指令的運(yùn)行場地問題. 而且在多核情況下,每個CPU核的每種特權(quán)模式都有自己獨(dú)立的棧空間.注意是特權(quán)模式下的棧空間,用戶模式的棧空間是由用戶(應(yīng)用)程序提供的.
官方概念
異常接管是操作系統(tǒng)對運(yùn)行期間發(fā)生的異常情況(芯片硬件異常)進(jìn)行處理的一系列動作，例如打印異常發(fā)生時當(dāng)前函數(shù)的調(diào)用棧信息、CPU現(xiàn)場信息、任務(wù)的堆棧情況等。 異常接管作為一種調(diào)測手段，可以在系統(tǒng)發(fā)生異常時給用戶提供有用的異常信息，譬如異常類型、發(fā)生異常時的系統(tǒng)狀態(tài)等，方便用戶定位分析問題。
鴻蒙的異常接管，在系統(tǒng)發(fā)生異常時的處理動作為：顯示異常發(fā)生時正在運(yùn)行的任務(wù)信息(包括任務(wù)名、任務(wù)號、堆棧大小等)，以及CPU現(xiàn)場等信息。
進(jìn)入和退出異常方式
異常接管切換需要處理好兩件事:
● 一個是代碼要切到哪個位置,也就是要重置PC寄存器,每種異常模式下的切換方式如圖:
● 另一個是要恢復(fù)每種模式的狀態(tài),即 CPSR(1個) 和 SPSR(共5個) 的關(guān)系,對M[4:0]的修改,如圖:
以下是M[4:0]在每種模式下具體操作方式:
棧幀
每個函數(shù)都有自己的棧空間，稱為棧幀。調(diào)用函數(shù)時，會創(chuàng)建子函數(shù)的棧幀，同時將函數(shù)入?yún)ⅰ⒕植孔兞俊⒓拇嫫魅霔！瑥母叩刂废虻偷刂飞L,也就是說棧底是高地址,棧頂是底地址. 詳見 系列篇之用棧方式篇
以ARM32 CPU架構(gòu)為例，每個棧幀中都會保存PC、LR、SP和FP寄存器的歷史值。 堆棧分析原理如下圖所示，實(shí)際堆棧信息根據(jù)不同CPU架構(gòu)有所差異，此處僅做示意。 圖中不同顏色的寄存器表示不同的函數(shù)。可以看到函數(shù)調(diào)用過程中，寄存器的保存。通過FP寄存器，棧回溯到異常函數(shù)的父函數(shù)，繼續(xù)按照規(guī)律對棧進(jìn)行解析，推出函數(shù)調(diào)用關(guān)系，方便用戶定位問題。
解讀
● LR寄存器(Link Register)，鏈接寄存器，指向函數(shù)的返回地址。
● R11：可以用作通用寄存器，在開啟特定編譯選項時可以用作幀指針寄存器FP，用來實(shí)現(xiàn)棧回溯功能。 GNU編譯器(gcc)默認(rèn)將R11作為存儲變量的通用寄存器，因而默認(rèn)情況下無法使用FP的棧回溯功能。為支持調(diào)用棧解析功能，需要在編譯參數(shù)中添加-fno-omit-frame-pointer選項，提示編譯器將R11作為FP使用。
● FP寄存器(Frame Point)，幀指針寄存器，指向當(dāng)前函數(shù)的父函數(shù)的棧幀起始地址。利用該寄存器可以得到父函數(shù)的棧幀，從棧幀中獲取父函數(shù)的FP，就可以得到祖父函數(shù)的棧幀，以此類推，可以追溯程序調(diào)用棧，得到函數(shù)間的調(diào)用關(guān)系。 當(dāng)系統(tǒng)發(fā)生異常時，系統(tǒng)打印異常函數(shù)的棧幀中保存的寄存器內(nèi)容，以及父函數(shù)、祖父函數(shù)的棧幀中的LR、FP寄存器內(nèi)容，用戶就可以據(jù)此追溯函數(shù)間的調(diào)用關(guān)系，定位異常原因。
六種異常模式實(shí)現(xiàn)代碼
- /* Define exception type ID */ //ARM處理器一共有7種工作模式，除了用戶和系統(tǒng)模式其余都叫異常工作模式
- #define OS_EXCEPT_RESET 0x00 //重置功能，例如：開機(jī)就進(jìn)入CPSR_SVC_MODE模式
- #define OS_EXCEPT_UNDEF_INSTR 0x01 //未定義的異常，就是others
- #define OS_EXCEPT_SWI 0x02 //軟中斷
- #define OS_EXCEPT_PREFETCH_ABORT 0x03 //預(yù)取異常(取指異常), 指令三步驟: 取指,譯碼,執(zhí)行,
- #define OS_EXCEPT_DATA_ABORT 0x04 //數(shù)據(jù)異常
- #define OS_EXCEPT_FIQ 0x05 //快中斷異常
- #define OS_EXCEPT_ADDR_ABORT 0x06 //地址異常
- #define OS_EXCEPT_IRQ 0x07 //普通中斷異常
地址異常處理(Address abort)
- @ Description: Address abort exception handler
- _osExceptAddrAbortHdl: @地址異常處理
- SUB LR, LR, #8 @ LR offset to return from this exception: -8.
- STMFD SP, {R0-R7} @ Push working registers, but don`t change SP.
- MOV R0, #OS_EXCEPT_ADDR_ABORT @ Set exception ID to OS_EXCEPT_ADDR_ABORT.
- B _osExceptDispatch @跳到異常分發(fā)統(tǒng)一處理
快中斷處理(fiq)
- @ Description: Fast interrupt request exception handler
- _osExceptFiqHdl: @快中斷異常處理
- SUB LR, LR, #4 @ LR offset to return from this exception: -4.
- STMFD SP, {R0-R7} @ Push working registers.
- MOV R0, #OS_EXCEPT_FIQ @ Set exception ID to OS_EXCEPT_FIQ.
- B _osExceptDispatch @ Branch to global exception handler.
解讀
● 快中斷處理時需禁用普通中斷
取指異常(Prefectch abort)
- @ Description: Prefectch abort exception handler
- _osExceptPrefetchAbortHdl:
- #ifdef LOSCFG_GDB
- #if __LINUX_ARM_ARCH__ >= 7
- GDB_HANDLE OsPrefetchAbortExcHandleEntry
- #endif
- #else
- SUB LR, LR, #4 @ LR offset to return from this exception: -4.
- STMFD SP, {R0-R7} @ Push working registers, but don`t change SP.
- MOV R5, LR
- MRS R1, SPSR
- MOV R0, #OS_EXCEPT_PREFETCH_ABORT @ Set exception ID to OS_EXCEPT_PREFETCH_ABORT.
- AND R4, R1, #CPSR_MASK_MODE @ Interrupted mode
- CMP R4, #CPSR_USER_MODE @ User mode
- BEQ _osExcPageFault @ Branch if user mode
- _osKernelExceptPrefetchAbortHdl:
- MOV LR, R5
- B _osExceptDispatch @ Branch to global exception handler.
- #endif
數(shù)據(jù)訪問異常(Data abort)
- @ Description: Data abort exception handler
- _osExceptDataAbortHdl: @數(shù)據(jù)異常處理,缺頁就屬于數(shù)據(jù)異常
- #ifdef LOSCFG_GDB
- #if __LINUX_ARM_ARCH__ >= 7
- GDB_HANDLE OsDataAbortExcHandleEntry
- #endif
- #else
- SUB LR, LR, #8 @ LR offset to return from this exception: -8.
- STMFD SP, {R0-R7} @ Push working registers, but don`t change SP.
- MOV R5, LR
- MRS R1, SPSR
- MOV R0, #OS_EXCEPT_DATA_ABORT @ Set exception ID to OS_EXCEPT_DATA_ABORT.
- B _osExcPageFault @跳到缺頁異常處理
- #endif
軟中斷處理(swi)
- @ Description: Software interrupt exception handler
- _osExceptSwiHdl: @軟中斷異常處理
- SUB SP, SP, #(4 * 16) @先申請16個棧空間用于處理本次軟中斷
- STMIA SP, {R0-R12} @保存R0-R12寄存器值
- MRS R3, SPSR @讀取本模式下的SPSR值
- MOV R4, LR @保存回跳寄存器LR
- AND R1, R3, #CPSR_MASK_MODE @ Interrupted mode 獲取中斷模式
- CMP R1, #CPSR_USER_MODE @ User mode 是否為用戶模式
- BNE OsKernelSVCHandler @ Branch if not user mode 非用戶模式下跳轉(zhuǎn)
- @ 當(dāng)為用戶模式時,獲取SP和LR寄出去值
- @ we enter from user mode, we need get the values of USER mode r13(sp) and r14(lr).
- @ stmia with ^ will return the user mode registers (provided that r15 is not in the register list).
- MOV R0, SP @獲取SP值,R0將作為OsArmA32SyscallHandle的參數(shù)
- STMFD SP!, {R3} @ Save the CPSR 入棧保存CPSR值
- ADD R3, SP, #(4 * 17) @ Offset to pc/cpsr storage 跳到PC/CPSR存儲位置
- STMFD R3!, {R4} @ Save the CPSR and r15(pc) 保存LR寄存器
- STMFD R3, {R13, R14}^ @ Save user mode r13(sp) and r14(lr) 保存用戶模式下的SP和LR寄存器
- SUB SP, SP, #4
- PUSH_FPU_REGS R1 @保存中斷模式(用戶模式模式)
- MOV FP, #0 @ Init frame pointer
- CPSIE I @開中斷,表明在系統(tǒng)調(diào)用期間可響應(yīng)中斷
- BLX OsArmA32SyscallHandle /*交給C語言處理系統(tǒng)調(diào)用*/
- CPSID I @執(zhí)行后續(xù)指令前必須先關(guān)中斷
- POP_FPU_REGS R1 @彈出FP值給R1
- ADD SP, SP,#4 @ 定位到保存舊SPSR值的位置
- LDMFD SP!, {R3} @ Fetch the return SPSR 彈出舊SPSR值
- MSR SPSR_cxsf, R3 @ Set the return mode SPSR 恢復(fù)該模式下的SPSR值
- @ we are leaving to user mode, we need to restore the values of USER mode r13(sp) and r14(lr).
- @ ldmia with ^ will return the user mode registers (provided that r15 is not in the register list)
- LDMFD SP!, {R0-R12} @恢復(fù)R0-R12寄存器
- LDMFD SP, {R13, R14}^ @ Restore user mode R13/R14 恢復(fù)用戶模式的R13/R14寄存器
- ADD SP, SP, #(2 * 4) @定位到保存舊PC值的位置
- LDMFD SP!, {PC}^ @ Return to user 切回用戶模式運(yùn)行
普通中斷處理(irq)
- OsIrqHandler: @硬中斷處理,此時已切換到硬中斷棧
- SUB LR, LR, #4
- /* push r0-r3 to irq stack */
- STMFD SP, {R0-R3} @r0-r3寄存器入 irq 棧
- SUB R0, SP, #(4 * 4)@r0 = sp - 16
- MRS R1, SPSR @獲取程序狀態(tài)控制寄存器
- MOV R2, LR @r2=lr
- /* disable irq, switch to svc mode */@超級用戶模式(SVC 模式)，主要用于 SWI(軟件中斷)和 OS(操作系統(tǒng))。
- CPSID i, #0x13 @切換到SVC模式,此處一切換,后續(xù)指令將入SVC的棧
- @CPSID i為關(guān)中斷指令,對應(yīng)的是CPSIE
- /* push spsr and pc in svc stack */
- STMFD SP!, {R1, R2} @實(shí)際是將 SPSR,和LR入棧,入棧順序為 R1,R2,SP自增
- STMFD SP, {LR} @LR再入棧,SP不自增
- AND R3, R1, #CPSR_MASK_MODE @獲取CPU的運(yùn)行模式
- CMP R3, #CPSR_USER_MODE @中斷是否發(fā)生在用戶模式
- BNE OsIrqFromKernel @中斷不發(fā)生在用戶模式下則跳轉(zhuǎn)到OsIrqFromKernel
- /* push user sp, lr in svc stack */
- STMFD SP, {R13, R14}^ @sp和LR入svc棧
解讀
● 普通中斷處理時可以響應(yīng)快中斷
未定義異常處理(undef)
- @ Description: Undefined instruction exception handler
- _osExceptUndefInstrHdl:@出現(xiàn)未定義的指令處理
- #ifdef LOSCFG_GDB
- GDB_HANDLE OsUndefIncExcHandleEntry
- #else
- @ LR offset to return from this exception: 0.
- STMFD SP, {R0-R7} @ Push working registers, but don`t change SP.
- MOV R0, #OS_EXCEPT_UNDEF_INSTR @ Set exception ID to OS_EXCEPT_UNDEF_INSTR.
- B _osExceptDispatch @ Branch to global exception handler.
- #endif
異常分發(fā)統(tǒng)一處理
- _osExceptDispatch: @異常模式統(tǒng)一分發(fā)處理
- MRS R2, SPSR @ Save CPSR before exception.
- MOV R1, LR @ Save PC before exception.
- SUB R3, SP, #(8 * 4) @ Save the start address of working registers.
- MSR CPSR_c, #(CPSR_INT_DISABLE | CPSR_SVC_MODE) @ Switch to SVC mode, and disable all interrupts
- MOV R5, SP
- EXC_SP_SET __exc_stack_top, OS_EXC_STACK_SIZE, R6, R7
- STMFD SP!, {R1} @ Push Exception PC
- STMFD SP!, {LR} @ Push SVC LR
- STMFD SP!, {R5} @ Push SVC SP
- STMFD SP!, {R8-R12} @ Push original R12-R8,
- LDMFD R3!, {R4-R11} @ Move original R7-R0 from exception stack to original stack.
- STMFD SP!, {R4-R11}
- STMFD SP!, {R2} @ Push task`s CPSR (i.e. exception SPSR).
- CMP R0, #OS_EXCEPT_DATA_ABORT @是數(shù)據(jù)異常嗎?
- BNE 1f @不是跳到 錨點(diǎn)1處
- MRC P15, 0, R8, C6, C0, 0 @R8=C6(內(nèi)存失效的地址) 0(訪問數(shù)據(jù)失效)
- MRC P15, 0, R9, C5, C0, 0 @R9=C5(內(nèi)存失效的狀態(tài)) 0(無效整個指令cache)
- B 3f @跳到錨點(diǎn)3處執(zhí)行
- 1: CMP R0, #OS_EXCEPT_PREFETCH_ABORT @是預(yù)取異常嗎?
- BNE 2f @不是跳到 錨點(diǎn)2處
- MRC P15, 0, R8, C6, C0, 2 @R8=C6(內(nèi)存失效的地址) 2(訪問指令失效)
- MRC P15, 0, R9, C5, C0, 1 @R9=C5(內(nèi)存失效的狀態(tài)) 1(虛擬地址)
- B 3f @跳到錨點(diǎn)3處執(zhí)行
- 2: MOV R8, #0
- MOV R9, #0
- 3: AND R2, R2, #CPSR_MASK_MODE
- CMP R2, #CPSR_USER_MODE @ User mode
- BNE 4f @不是用戶模式
- STMFD SP, {R13, R14}^ @ save user mode sp and lr
- 4:
- SUB SP, SP, #(4 * 2) @sp=sp-(4*2)
非常重要的ARM37個寄存器
詳見 系列篇之寄存器篇
結(jié)尾
以上為異常接管對應(yīng)的代碼處理,具體每種異常發(fā)生的場景和代碼細(xì)節(jié)處理,因內(nèi)容太多,太復(fù)雜,系列篇后續(xù)將分篇一一分析.敬請關(guān)注!
參與貢獻(xiàn)
● 訪問注解倉庫地址
● Fork 本倉庫 >> 新建 Feat_xxx 分支 >> 提交代碼注解 >> 新建 Pull Request
● 新建 Issue
51CTO和華為官方合作共建的鴻蒙技術(shù)社區(qū)
